stow/oh-my-zsh/.oh-my-zsh/themes/avit.zsh-theme

   1 # AVIT ZSH Theme
   2
   3 # settings
   4 typeset +H _current_dir="%{$fg_bold[blue]%}%3~%{$reset_color%} "
   5 typeset +H _return_status="%{$fg_bold[red]%}%(?..⍉)%{$reset_color%}"
   6 typeset +H _hist_no="%{$fg[grey]%}%h%{$reset_color%}"
   7
   8 PROMPT='
   9 $(_user_host)${_current_dir} $(git_prompt_info) $(ruby_prompt_info)
  10 %{%(!.${fg[red]}.${fg[white]})%}▶%{$reset_color%} '
  11
  12 PROMPT2='%{%(!.${fg[red]}.${fg[white]})%}◀%{$reset_color%} '
  13
  14 RPROMPT='$(vi_mode_prompt_info)%{$(echotc UP 1)%}$(_git_time_since_commit) $(git_prompt_status) ${_return_status}%{$(echotc DO 1)%}'
  15
  16 function _user_host() {
  17   local me
  18   if [[ -n $SSH_CONNECTION ]]; then
  19     me="%n@%m"
  20   elif [[ $LOGNAME != $USERNAME ]]; then
  21     me="%n"
  22   fi
  23   if [[ -n $me ]]; then
  24     echo "%{$fg[cyan]%}$me%{$reset_color%}:"
  25   fi
  26 }
  27
  28 # Determine the time since last commit. If branch is clean,
  29 # use a neutral color, otherwise colors will vary according to time.
  30 function _git_time_since_commit() {
  31   local last_commit now seconds_since_last_commit
  32   local minutes hours days years commit_age
  33   # Only proceed if there is actually a commit.
  34   if last_commit=$(command git -c log.showSignature=false log --format='%at' -1 2>/dev/null); then
  35     now=$(date +%s)
  36     seconds_since_last_commit=$((now-last_commit))
  37
  38     # Totals
  39     minutes=$((seconds_since_last_commit / 60))
  40     hours=$((minutes / 60))
  41     days=$((hours / 24))
  42     years=$((days / 365))
  43
  44     if [[ $years -gt 0 ]]; then
  45       commit_age="${years}y$((days % 365 ))d"
  46     elif [[ $days -gt 0 ]]; then
  47       commit_age="${days}d$((hours % 24))h"
  48     elif [[ $hours -gt 0 ]]; then
  49       commit_age+="${hours}h$(( minutes % 60 ))m"
  50     else
  51       commit_age="${minutes}m"
  52     fi
  53
  54     echo "${ZSH_THEME_GIT_TIME_SINCE_COMMIT_NEUTRAL}${commit_age}%{$reset_color%}"
  55   fi
  56 }
  57
  58 MODE_INDICATOR="%{$fg_bold[yellow]%}❮%{$reset_color%}%{$fg[yellow]%}❮❮%{$reset_color%}"
  59
  60 # Git prompt settings
  61 ZSH_THEME_GIT_PROMPT_PREFIX="%{$fg[green]%}"
  62 ZSH_THEME_GIT_PROMPT_SUFFIX="%{$reset_color%}"
  63 ZSH_THEME_GIT_PROMPT_DIRTY=" %{$fg[red]%}✗%{$reset_color%}"
  64 ZSH_THEME_GIT_PROMPT_CLEAN=" %{$fg[green]%}✔%{$reset_color%}"
  65 ZSH_THEME_GIT_PROMPT_ADDED="%{$fg[green]%}✚ "
  66 ZSH_THEME_GIT_PROMPT_MODIFIED="%{$fg[yellow]%}⚑ "
  67 ZSH_THEME_GIT_PROMPT_DELETED="%{$fg[red]%}✖ "
  68 ZSH_THEME_GIT_PROMPT_RENAMED="%{$fg[blue]%}▴ "
  69 ZSH_THEME_GIT_PROMPT_UNMERGED="%{$fg[cyan]%}§ "
  70 ZSH_THEME_GIT_PROMPT_UNTRACKED="%{$fg[white]%}◒ "
  71
  72 # Ruby prompt settings
  73 ZSH_THEME_RUBY_PROMPT_PREFIX="%{$fg[grey]%}"
  74 ZSH_THEME_RUBY_PROMPT_SUFFIX="%{$reset_color%}"
  75
  76 # Colors vary depending on time lapsed.
  77 ZSH_THEME_GIT_TIME_SINCE_COMMIT_SHORT="%{$fg[green]%}"
  78 ZSH_THEME_GIT_TIME_SHORT_COMMIT_MEDIUM="%{$fg[yellow]%}"
  79 ZSH_THEME_GIT_TIME_SINCE_COMMIT_LONG="%{$fg[red]%}"
  80 ZSH_THEME_GIT_TIME_SINCE_COMMIT_NEUTRAL="%{$fg[white]%}"
  81
  82 # LS colors, made with https://geoff.greer.fm/lscolors/
  83 export LSCOLORS="exfxcxdxbxegedabagacad"
  84 export LS_COLORS='di=34;40:ln=35;40:so=32;40:pi=33;40:ex=31;40:bd=34;46:cd=34;43:su=0;41:sg=0;46:tw=0;42:ow=0;43:'
  85 export GREP_COLOR='1;33'