stow/oh-my-zsh/.oh-my-zsh/plugins/term_tab/term_tab.plugin.zsh

   1 # Copyright (C) 2014 Julian Vetter <death.jester@web.de>
   2 #
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 2 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program; if not, write to the Free Software
  15 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301 USA
  16
  17 function _term_list(){
  18   local -a expl
  19   local -au dirs
  20
  21   PREFIX="$IPREFIX$PREFIX"
  22   IPREFIX=
  23   SUFFIX="$SUFFIX$ISUFFIX"
  24   ISUFFIX=
  25
  26   [[ -o magicequalsubst ]] && compset -P '*='
  27
  28   case $OSTYPE in
  29     solaris*) dirs=( ${(M)${${(f)"$(pgrep -U $UID -x zsh|xargs pwdx)"}:#$$:*}%%/*} ) ;;
  30     linux*) dirs=( /proc/${^$(pidof zsh):#$$}/cwd(N:A) ) ;;
  31   esac
  32   dirs=( ${(D)dirs} )
  33
  34   compstate[pattern_match]='*'
  35   _wanted directories expl 'current directory from other shell' \
  36       compadd -Q -M "r:|/=* r:|=*" -f -a dirs
  37 }
  38
  39 zle -C term_list menu-complete _generic
  40 bindkey "^v" term_list
  41 zstyle ':completion:term_list::::' completer _term_list