stow/oh-my-zsh/.oh-my-zsh/plugins/nvm/nvm.plugin.zsh

   1 # See https://github.com/nvm-sh/nvm#installation-and-update
   2 if [[ -z "$NVM_DIR" ]]; then
   3   if [[ -d "$HOME/.nvm" ]]; then
   4     export NVM_DIR="$HOME/.nvm"
   5   elif [[ -d "${XDG_CONFIG_HOME:-$HOME/.config}/nvm" ]]; then
   6     export NVM_DIR="${XDG_CONFIG_HOME:-$HOME/.config}/nvm"
   7   elif (( $+commands[brew] )); then
   8     NVM_HOMEBREW="${NVM_HOMEBREW:-${HOMEBREW_PREFIX:-$(brew --prefix)}/opt/nvm}"
   9     if [[ -d "$NVM_HOMEBREW" ]]; then
  10       export NVM_DIR="$NVM_HOMEBREW"
  11     fi
  12   fi
  13 fi
  14
  15 # Don't try to load nvm if command already available
  16 # Note: nvm is a function so we need to use `which`
  17 which nvm &>/dev/null && return
  18
  19 if (( $+NVM_LAZY )); then
  20   # Call nvm when first using nvm, node, npm, pnpm, yarn or $NVM_LAZY_CMD
  21   function nvm node npm pnpm yarn $NVM_LAZY_CMD {
  22     unfunction nvm node npm pnpm yarn $NVM_LAZY_CMD
  23     # Load nvm if it exists in $NVM_DIR
  24     [[ -f "$NVM_DIR/nvm.sh" ]] && source "$NVM_DIR/nvm.sh"
  25     "$0" "$@"
  26   }
  27 elif [[ -f "$NVM_DIR/nvm.sh" ]]; then
  28   # Load nvm if it exists in $NVM_DIR
  29   source "$NVM_DIR/nvm.sh"
  30 else
  31   return
  32 fi
  33
  34 # Autoload nvm when finding a .nvmrc file in the current directory
  35 # Adapted from: https://github.com/nvm-sh/nvm#zsh
  36 if (( $+NVM_AUTOLOAD )); then
  37   load-nvmrc() {
  38     local node_version="$(nvm version)"
  39     local nvmrc_path="$(nvm_find_nvmrc)"
  40
  41     if [[ -n "$nvmrc_path" ]]; then
  42       local nvmrc_node_version=$(nvm version "$(cat "${nvmrc_path}")")
  43
  44       if [[ "$nvmrc_node_version" = "N/A" ]]; then
  45         nvm install
  46       elif [[ "$nvmrc_node_version" != "$node_version" ]]; then
  47         nvm use
  48       fi
  49     elif [[ "$node_version" != "$(nvm version default)" ]]; then
  50       echo "Reverting to nvm default version"
  51       nvm use default
  52     fi
  53   }
  54
  55   autoload -U add-zsh-hook
  56   add-zsh-hook chpwd load-nvmrc
  57
  58   load-nvmrc
  59 fi
  60
  61 # Load nvm bash completion
  62 for nvm_completion in "$NVM_DIR/bash_completion" "$NVM_HOMEBREW/etc/bash_completion.d/nvm"; do
  63   if [[ -f "$nvm_completion" ]]; then
  64     # Load bashcompinit
  65     autoload -U +X bashcompinit && bashcompinit
  66     # Bypass compinit call in nvm bash completion script. See:
  67     # https://github.com/nvm-sh/nvm/blob/4436638/bash_completion#L86-L93
  68     ZSH_VERSION= source "$nvm_completion"
  69     break
  70   fi
  71 done
  72
  73 unset NVM_HOMEBREW NVM_LAZY NVM_AUTOLOAD nvm_completion