stow/oh-my-zsh/.oh-my-zsh/plugins/jenv/jenv.plugin.zsh

   1 jenvdirs=("$HOME/.jenv" "/usr/local/bin/jenv" "/usr/local/jenv" "/opt/jenv")
   2
   3 FOUND_JENV=0
   4 for jenvdir in $jenvdirs; do
   5     if [[ -d "${jenvdir}/bin" ]]; then
   6         FOUND_JENV=1
   7         break
   8     fi
   9 done
  10
  11 if [[ $FOUND_JENV -eq 0 ]]; then
  12     if (( $+commands[brew] )) && jenvdir="$(brew --prefix jenv)"; then
  13         [[ -d "${jenvdir}/bin" ]] && FOUND_JENV=1
  14     fi
  15 fi
  16
  17 if [[ $FOUND_JENV -eq 1 ]]; then
  18     (( $+commands[jenv] )) || export PATH="${jenvdir}/bin:$PATH"
  19     eval "$(jenv init - zsh)"
  20
  21     function jenv_prompt_info() {
  22       local version="$(jenv version-name 2>/dev/null)"
  23       echo "${version:gs/%/%%}"
  24     }
  25
  26     if [[ -d "${jenvdir}/versions" ]]; then
  27         export JENV_ROOT=$jenvdir
  28     fi
  29 else
  30     function jenv_prompt_info() {
  31       local version="$(java -version 2>&1 | cut -d' ' -f2)"
  32       echo "system: ${version:gs/%/%%}"
  33     }
  34 fi
  35
  36 unset jenvdir jenvdirs FOUND_JENV