stow/oh-my-zsh/.oh-my-zsh/plugins/gcloud/gcloud.plugin.zsh

   1 #####################################################
   2 # gcloud plugin for oh-my-zsh                       #
   3 # Author: Ian Chesal (github.com/ianchesal)         #
   4 #####################################################
   5
   6 if [[ -z "${CLOUDSDK_HOME}" ]]; then
   7   search_locations=(
   8     "$HOME/google-cloud-sdk"
   9     "/usr/local/Caskroom/google-cloud-sdk/latest/google-cloud-sdk"
  10     "/opt/homebrew/Caskroom/google-cloud-sdk/latest/google-cloud-sdk"
  11     "/usr/share/google-cloud-sdk"
  12     "/snap/google-cloud-sdk/current"
  13     "/usr/lib/google-cloud-sdk"
  14     "/usr/lib64/google-cloud-sdk"
  15     "/opt/google-cloud-sdk"
  16     "/opt/local/libexec/google-cloud-sdk"
  17   )
  18
  19   for gcloud_sdk_location in $search_locations; do
  20     if [[ -d "${gcloud_sdk_location}" ]]; then
  21       CLOUDSDK_HOME="${gcloud_sdk_location}"
  22       break
  23     fi
  24   done
  25   unset search_locations gcloud_sdk_location
  26 fi
  27
  28 if (( ${+CLOUDSDK_HOME} )); then
  29   # Only source this if gcloud isn't already on the path
  30   if (( ! $+commands[gcloud] )); then
  31     if [[ -f "${CLOUDSDK_HOME}/path.zsh.inc" ]]; then
  32       source "${CLOUDSDK_HOME}/path.zsh.inc"
  33     fi
  34   fi
  35
  36   # Look for completion file in different paths
  37   for comp_file (
  38     "${CLOUDSDK_HOME}/completion.zsh.inc"             # default location
  39     "/usr/share/google-cloud-sdk/completion.zsh.inc"  # apt-based location
  40   ); do
  41     if [[ -f "${comp_file}" ]]; then
  42       source "${comp_file}"
  43       break
  44     fi
  45   done
  46   unset comp_file
  47
  48   export CLOUDSDK_HOME
  49 fi