stow/oh-my-zsh/.oh-my-zsh/plugins/bgnotify/bgnotify.plugin.zsh

   1 #!/usr/bin/env zsh
   2
   3 ## setup ##
   4
   5 [[ -o interactive ]] || return #interactive only!
   6 zmodload zsh/datetime || { print "can't load zsh/datetime"; return } # faster than date()
   7 autoload -Uz add-zsh-hook || { print "can't add zsh hook!"; return }
   8
   9 (( ${+bgnotify_threshold} )) || bgnotify_threshold=5 #default 10 seconds
  10
  11
  12 ## definitions ##
  13
  14 if ! (type bgnotify_formatted | grep -q 'function'); then ## allow custom function override
  15   function bgnotify_formatted { ## args: (exit_status, command, elapsed_seconds)
  16     elapsed="$(( $3 % 60 ))s"
  17     (( $3 >= 60 )) && elapsed="$((( $3 % 3600) / 60 ))m $elapsed"
  18     (( $3 >= 3600 )) && elapsed="$(( $3 / 3600 ))h $elapsed"
  19     [ $1 -eq 0 ] && bgnotify "#win (took $elapsed)" "$2" || bgnotify "#fail (took $elapsed)" "$2"
  20   }
  21 fi
  22
  23 currentAppId () {
  24   if (( $+commands[osascript] )); then
  25     osascript -e 'tell application (path to frontmost application as text) to id' 2>/dev/null
  26   fi
  27 }
  28
  29 currentWindowId () {
  30   if hash osascript 2>/dev/null; then #osx
  31     osascript -e 'tell application (path to frontmost application as text) to id of front window' 2&> /dev/null || echo "0"
  32   elif (hash notify-send 2>/dev/null || hash kdialog 2>/dev/null); then #ubuntu!
  33     xprop -root 2> /dev/null | awk '/NET_ACTIVE_WINDOW/{print $5;exit} END{exit !$5}' || echo "0"
  34   else
  35     echo $EPOCHSECONDS #fallback for windows
  36   fi
  37 }
  38
  39 bgnotify () { ## args: (title, subtitle)
  40   if hash terminal-notifier 2>/dev/null; then #osx
  41     local term_id="$bgnotify_appid"
  42     if [[ -z "$term_id" ]]; then
  43       case "$TERM_PROGRAM" in
  44       iTerm.app) term_id='com.googlecode.iterm2' ;;
  45       Apple_Terminal) term_id='com.apple.terminal' ;;
  46       esac
  47     fi
  48
  49     ## now call terminal-notifier, (hopefully with $term_id!)
  50     if [[ -z "$term_id" ]]; then
  51       terminal-notifier -message "$2" -title "$1" >/dev/null
  52     else
  53       terminal-notifier -message "$2" -title "$1" -activate "$term_id" -sender "$term_id" >/dev/null
  54     fi
  55   elif hash growlnotify 2>/dev/null; then #osx growl
  56     growlnotify -m "$1" "$2"
  57   elif hash notify-send 2>/dev/null; then #ubuntu gnome!
  58     notify-send "$1" "$2"
  59   elif hash kdialog 2>/dev/null; then #ubuntu kde!
  60     kdialog --title "$1" --passivepopup  "$2" 5
  61   elif hash notifu 2>/dev/null; then #cygwyn support!
  62     notifu /m "$2" /p "$1"
  63   fi
  64 }
  65
  66
  67 ## Zsh hooks ##
  68
  69 bgnotify_begin() {
  70   bgnotify_timestamp=$EPOCHSECONDS
  71   bgnotify_lastcmd="${1:-$2}"
  72   bgnotify_appid="$(currentAppId)"
  73   bgnotify_windowid=$(currentWindowId)
  74 }
  75
  76 bgnotify_end() {
  77   didexit=$?
  78   elapsed=$(( EPOCHSECONDS - bgnotify_timestamp ))
  79   past_threshold=$(( elapsed >= bgnotify_threshold ))
  80   if (( bgnotify_timestamp > 0 )) && (( past_threshold )); then
  81     if [[ $(currentAppId) != "$bgnotify_appid" || $(currentWindowId) != "$bgnotify_windowid" ]]; then
  82       print -n "\a"
  83       bgnotify_formatted "$didexit" "$bgnotify_lastcmd" "$elapsed"
  84     fi
  85   fi
  86   bgnotify_timestamp=0 #reset it to 0!
  87 }
  88
  89 ## only enable if a local (non-ssh) connection
  90 if [ -z "$SSH_CLIENT" ] && [ -z "$SSH_TTY" ]; then
  91   add-zsh-hook preexec bgnotify_begin
  92   add-zsh-hook precmd bgnotify_end
  93 fi